Rename File Extension (AppleScript Folder Action)

Rename file extension (Folder Action)

Attach this script as a folder action to rename the file extension of files added to the folder. Open the script, edit the properties at the top of the script to enter the extension to look for and the resulting extension to change it to. Save the script to the Folder Action Scripts folder and then attach it to the folder. Everything after that is automatic. If necessary, the script renames files, starting with the base file name, to unique file names to avoiding overwriting files. Optionally place the renamed and original files into separate sub-folders and open the renamed file with its default application.

Examples:
This folder action is attached to the browser’s Downloads folder to change show_temp.pl files to show_temp.pdf and open the renamed file in the PDF viewer.
File downloaded: show_temp.pl is renamed to show_temp.pdf.
File downloaded: show_temp-1.pl is renamed to show_temp-1.1.pdf (when there is a preexisting show_temp-1.pdf).

(*
We can not put both the renamed file and the added file in this_folder without triggering the Folder Action. We can avoid triggering the action by saving a duplicate of the orginal in a subfolder and renaming the original, or, leaving the original file as is and saving the renamed duplicate file in a subfolder. Leaving one of the _foldernames empty will force that respective file to be left in this_folder (the file will either be renamed or left unchanged).  If both _foldername properties are empty, the folder action will rename the added file in place without saving a copy of the original file - the rename_only property is forced to true. 
*)

property results_foldername : "show_temp PDFs" -- Renamed file destination folder. If empty then this_folder is used, else the named folder will be created as a subfolder of this_folder.
property originals_foldername : "" -- Original file destination folder. If empty then this_folder is used, else the named folder will be created as a subfolder of this_folder.
property new_extension : "pdf" -- The extension to change to.
property type_list : {} -- The list of file types to process (optional).  Comma separated values, e.g. {"pxx", "DET"}.
property extension_list : {"pl"} -- The list of file extensions to check if there is no file type. Comma separated values, without "dot" prefix.
property open_result : true -- Open the renamed file in file's default application.
property rename_only : false -- Original file is renamed in place, and a copy of it is not saved.

on adding folder items to this_folder after receiving these_items
	--display dialog "Items added."
	if results_foldername is "" and originals_foldername is "" then
		set rename_only to true -- If both folders are empty, restrict to rename_only (avoid triggering Folder Action).
	end if
	tell application "Finder" --Set up the folders to save original file and store the converted file.
		if results_foldername is "" or rename_only then
			set the results_folder to this_folder as alias -- Original is rename in place. No move/save involved.
		else
			if not (exists folder results_foldername of this_folder) then
				make new folder at this_folder with properties {name:results_foldername}
			end if
			set the results_folder to (folder results_foldername of this_folder) as alias
		end if
		if originals_foldername is "" then
			set the originals_folder to this_folder as alias
		else
			if not (exists folder originals_foldername of this_folder) then
				make new folder at this_folder with properties {name:originals_foldername}
			end if
			set the originals_folder to (folder originals_foldername of this_folder) as alias
		end if
	end tell
	try
		repeat with i from 1 to number of items in these_items
			set this_item to item i of these_items
			set the item_info to the info for this_item
			if (alias of the item_info is false and the file type of the item_info is in the type_list) or (the name extension of the item_info is in the extension_list) then
				tell application "Finder"
					if rename_only then -- Rename only does not save the original.
						set the new_name to my unique_filename(this_item, results_folder, new_extension) -- Get unique name in destination folder.
						set the name of this_item to new_name -- Rename the added file.
					else
						set temp_path to path to temporary items folder
						set the source_file to (duplicate this_item to the temp_path with replacing) -- Copy file to temporary folder so we can work on it.
						set the new_name to my unique_filename(this_item, results_folder, new_extension) -- Get name for coverted file in results folder, insuring uniqueness,.
						if results_foldername is "" then -- Save original to the named folder and rename the original file in place.
							set the source_name to my unique_filename(this_item, originals_folder, "") -- Get name for original file in original folder, insuring uniqueness.
							my delete_file(source_name, temp_path) -- Avoid renaming errors.
							set the name of source_file to source_name -- Rename to unique original name file in temporary location.
							move document file source_name of temp_path to the originals_folder with replacing
							set the name of this_item to new_name -- Rename the added file in its original location.
						else if originals_foldername is "" then -- Save the renamed file to the named folder and leave the original file alone (it was renamed by the Finder/Application already).
							my delete_file(new_name, temp_path) -- Avoid renaming errors.
							set the name of source_file to new_name -- Rename to converted name file in temporary location.
							move document file new_name of temp_path to the results_folder with replacing
						else -- Both foldernames are not empty. Move files to the folders.
							-- Save renamed file first.
							my delete_file(new_name, temp_path) -- Avoid renaming errors.
							set the name of source_file to new_name -- Rename to converted name file in temporary location.
							move document file new_name of temp_path to the results_folder with replacing
							set the source_file to (move this_item to the temp_path with replacing) as alias -- Copy file to temporary folder so we can work on it.
							set the source_name to my unique_filename(this_item, originals_folder, "") -- Get name for original file in original folder, insuring uniqueness.
							if name of this_item is not equal to source_name then
								my delete_file(source_name, temp_path) -- Avoid renaming errors.
							end if
							set the name of source_file to source_name -- Rename to unique original name file in temporary location.
							move document file source_name of temp_path to the originals_folder with replacing
						end if
						
					end if
					
					if open_result then
						open (results_folder as string) & new_name
					end if
					
				end tell
				
			end if
		end repeat
	on error error_message number error_number
		if the error_number is not -128 then
			tell application "Finder"
				activate
				display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
			end tell
		end if
	end try
end adding folder items to

on unique_filename(this_item, target_folder, new_extension) -- Returns a filename unique to the files in the passed folder.
	tell application "Finder"
		set the file_name to the name of this_item
		set file_extension to the name extension of this_item
		if the file_extension is "" then
			set the trimmed_name to the file_name
		else
			set the trimmed_name to text 1 thru -((length of file_extension) + 2) of the file_name
		end if
		if the new_extension is "" then
			set target_name to file_name
			set target_extension to file_extension
		else
			set target_extension to new_extension
			set target_name to (the trimmed_name & "." & target_extension) as string
		end if
		if (exists document file target_name of target_folder) then
			set the name_increment to 1
			repeat
				set the target_name to (the trimmed_name & "." & (name_increment as string) & "." & target_extension) as string
				if not (exists document file target_name of the target_folder) then
					exit repeat
				else
					set the name_increment to the name_increment + 1
				end if
			end repeat
		end if
	end tell
	return the target_name
end unique_filename

on delete_file(file_name, file_path) -- Deletes a file only if it exists.
	tell application "Finder"
		if (exists document file file_name of file_path) then
			delete document file file_name of file_path
		end if
	end tell
end delete_file

* In the AppleScript Editor, use usual text editing commands to change the property values you want changed and save the file to the path: “[Hard Disk]:Library:Scripts:Folder Action Scripts:”. Control-click the folder on which you wish to attach the folder action and choose Folder Action Setup from the contextual menu. Select your saved folder action script and check the Enable Folder Actions check box. Close the Folder Action Setup window and test your setup by adding a file to the folder on which you have attached the action.

Leave a Reply Cancel reply

Recent Posts

Recent Comments

Archives

Categories

Administer